use scripting additions
use framework "Foundation"

on run {input, parameters}
	repeat with fileItem in input
		--ファイル名を取得
		tell application "Finder"
			set oldFileName to name of fileItem as string
		end tell
		
		--正規表現を使って分割
		set matchResultList to regexMatches(oldFileName, "(G.)(\\d{2})(\\d{4})(.+)")
		if (length of matchResultList = 5) and (item 5 of matchResultList = ".MP4") then
			--正規表現の結果が5で、拡張子部分が.MP4の時のみ処理を続ける
			set newFileName to item 2 of matchResultList & item 4 of matchResultList & "-" & item 3 of matchResultList & item 5 of matchResultList
			
			--リネームする			
			tell application "Finder"
				try
					set (name of fileItem) to (newFileName as string)
				on error
					display dialog "error"
				end try
			end tell
		end if
	end repeat
	
	return input
end run

to regexMatches(aText as text, pattern as text)
	set regularExpression to current application's NSRegularExpression's regularExpressionWithPattern:pattern options:0 |error|:(missing value)
	set aString to current application's NSString's stringWithString:aText
	set matches to regularExpression's matchesInString:aString options:0 range:{location:0, |length|:aString's |length|()}
	
	repeat with match in matches
		set matchResult to {}
		repeat with i from 0 to (match's numberOfRanges as integer) - 1
			set end of matchResult to (aString's substringWithRange:(match's rangeAtIndex:i)) as text
		end repeat
	end repeat
	return matchResult
end regexMatches